oneDNN_2: reintroduce and unbreak, rocmPackages.migraphx: use oneDNN_2

pkgs/by-name/on/oneDNN_2/package.nix

@@ -0,0 +1,60 @@
+{
+  cmake,
+  fetchFromGitHub,
+  lib,
+  stdenv,
+}:
+
+# This was originally called mkl-dnn, then it was renamed to dnnl, and it has
+# just recently been renamed again to oneDNN. See here for details:
+# https://github.com/oneapi-src/oneDNN#oneapi-deep-neural-network-library-onednn
+# oneDNN_2 is currently only consumed by rocmPackages.migraphx and likely
+# to be dropped once migraphx can migrate to 3
+stdenv.mkDerivation (finalAttrs: {
+  pname = "oneDNN";
+  version = "2.7.5";
+
+  src = fetchFromGitHub {
+    owner = "oneapi-src";
+    repo = "oneDNN";
+    rev = "v${finalAttrs.version}";
+    sha256 = "sha256-oMPBORAdL2rk2ewyUrInYVHYBRvuvNX4p4rwykO3Rhs=";
+  };
+
+  # Substituting for CMake 4 compat.
+  # There's an upstream patch in v3 which does not cleanly apply.
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace-fail "cmake_minimum_required(VERSION 2.8.12)" \
+      "cmake_minimum_required(VERSION 2.8.12...3.13)"
+  '';
+
+  outputs = [
+    "out"
+    "dev"
+    "doc"
+  ];
+
+  nativeBuildInputs = [ cmake ];
+
+  # Tests fail on some Hydra builders, because they do not support SSE4.2.
+  doCheck = false;
+
+  # Fixup bad cmake paths
+  postInstall = ''
+    substituteInPlace $out/lib/cmake/dnnl/dnnl-config.cmake \
+      --replace "\''${PACKAGE_PREFIX_DIR}/" ""
+
+    substituteInPlace $out/lib/cmake/dnnl/dnnl-targets.cmake \
+      --replace "\''${_IMPORT_PREFIX}/" ""
+  '';
+
+  meta = {
+    changelog = "https://github.com/oneapi-src/oneDNN/releases/tag/v${finalAttrs.version}";
+    description = "oneAPI Deep Neural Network Library (oneDNN)";
+    homepage = "https://01.org/oneDNN";
+    license = lib.licenses.asl20;
+    teams = [ lib.teams.rocm ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/development/rocm-modules/6/migraphx/default.nix

@@ -21,7 +21,9 @@
   boost,
   msgpack-cxx,
   sqlite,
-  oneDNN,
+  # TODO(@LunNova): Swap to `oneDNN` once v3 is supported
+  # Upstream issue: https://github.com/ROCm/AMDMIGraphX/issues/4351
+  oneDNN_2,
   blaze,
   texliveSmall,
   doxygen,
@@ -53,15 +55,6 @@ let
       ]
     )
   );
-  oneDNN' = oneDNN.overrideAttrs rec {
-    version = "2.7.5";
-    src = fetchFromGitHub {
-      owner = "oneapi-src";
-      repo = "oneDNN";
-      tag = "v${version}";
-      hash = "sha256-oMPBORAdL2rk2ewyUrInYVHYBRvuvNX4p4rwykO3Rhs=";
-    };
-  };
 in
 stdenv.mkDerivation (finalAttrs: {
   pname = "migraphx";
@@ -120,7 +113,7 @@ stdenv.mkDerivation (finalAttrs: {
     boost
     msgpack-cxx
     sqlite
-    oneDNN'
+    oneDNN_2
     blaze
     python3Packages.pybind11
     python3Packages.onnx

pkgs/top-level/aliases.nix

@@ -1928,7 +1928,6 @@ mapAliases {
   odoo15 = throw "odoo15 has been removed from nixpkgs as it is unsupported; migrate to a newer version of odoo"; # Added 2025-05-06
   offrss = throw "offrss has been removed due to lack of upstream maintenance; consider using another rss reader"; # Added 2025-06-01
   oil = lib.warnOnInstantiate "Oil has been replaced with the faster native C++ version and renamed to 'oils-for-unix'. See also https://github.com/oils-for-unix/oils/wiki/Oils-Deployments" oils-for-unix; # Added 2024-10-22
-  oneDNN_2 = throw "oneDNN_2 has been removed as it was only used by rocmPackages.migraphx"; # added 2025-07-18
   onevpl-intel-gpu = lib.warnOnInstantiate "onevpl-intel-gpu has been renamed to vpl-gpu-rt" vpl-gpu-rt; # Added 2024-06-04
   openai-triton-llvm = triton-llvm; # added 2024-07-18
   openai-whisper-cpp = whisper-cpp; # Added 2024-12-13