igraph: 0.10.17 -> 1.0.0

pkgs/by-name/ha/hal-hardware-analyzer/package.nix

@@ -5,7 +5,7 @@
   cmake,
   fetchFromGitHub,
   graphviz,
-  igraph,
+  igraph_0, # https://github.com/emsec/hal/issues/623
   llvmPackages,
   ninja,
   nlohmann_json,
@@ -51,7 +51,7 @@ stdenv.mkDerivation rec {
     libsForQt5.qtsvg
     boost
     rapidjson
-    igraph
+    igraph_0
     nlohmann_json
     spdlog
     graphviz

pkgs/by-name/ig/igraph/package.nix

@@ -25,13 +25,13 @@ assert (blas.isILP64 == lapack.isILP64 && blas.isILP64 == arpack.isILP64 && !bla
 
 stdenv.mkDerivation (finalAttrs: {
   pname = "igraph";
-  version = "0.10.17";
+  version = "1.0.0";
 
   src = fetchFromGitHub {
     owner = "igraph";
     repo = "igraph";
-    rev = finalAttrs.version;
-    hash = "sha256-NzLn2GXpMgwE8fY1vp5SU0Y7EfyVpQfphGdqU6sQGW4=";
+    tag = finalAttrs.version;
+    hash = "sha256-SwcihzISSmeVhpMrysOhWrUzVVuB4ZBVEjC0vHJwrdw=";
   };
 
   postPatch = ''
@@ -107,7 +107,7 @@ stdenv.mkDerivation (finalAttrs: {
   meta = with lib; {
     description = "C library for complex network analysis and graph theory";
     homepage = "https://igraph.org/";
-    changelog = "https://github.com/igraph/igraph/blob/${finalAttrs.src.rev}/CHANGELOG.md";
+    changelog = "https://github.com/igraph/igraph/blob/${finalAttrs.src.tag}/CHANGELOG.md";
     license = licenses.gpl2Plus;
     platforms = platforms.all;
     maintainers = with maintainers; [

pkgs/by-name/ig/igraph_0/package.nix

@@ -0,0 +1,112 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  arpack,
+  bison,
+  blas,
+  cmake,
+  flex,
+  fop,
+  glpk,
+  gmp,
+  hal-hardware-analyzer,
+  lapack,
+  libxml2,
+  libxslt,
+  llvmPackages,
+  pkg-config,
+  plfit,
+  python3,
+  sourceHighlight,
+  xmlto,
+}:
+
+assert (blas.isILP64 == lapack.isILP64 && blas.isILP64 == arpack.isILP64 && !blas.isILP64);
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "igraph";
+  version = "0.10.17";
+
+  src = fetchFromGitHub {
+    owner = "igraph";
+    repo = "igraph";
+    tag = finalAttrs.version;
+    hash = "sha256-NzLn2GXpMgwE8fY1vp5SU0Y7EfyVpQfphGdqU6sQGW4=";
+  };
+
+  postPatch = ''
+    echo "${finalAttrs.version}" > IGRAPH_VERSION
+  '';
+
+  outputs = [
+    "out"
+    "dev"
+    "doc"
+  ];
+
+  nativeBuildInputs = [
+    bison
+    cmake
+    flex
+    fop
+    libxml2
+    libxslt
+    pkg-config
+    python3
+    sourceHighlight
+    xmlto
+  ];
+
+  buildInputs = [
+    arpack
+    blas
+    glpk
+    gmp
+    lapack
+    libxml2
+    plfit
+  ]
+  ++ lib.optionals stdenv.cc.isClang [
+    llvmPackages.openmp
+  ];
+
+  cmakeFlags = [
+    "-DIGRAPH_USE_INTERNAL_BLAS=OFF"
+    "-DIGRAPH_USE_INTERNAL_LAPACK=OFF"
+    "-DIGRAPH_USE_INTERNAL_ARPACK=OFF"
+    "-DIGRAPH_USE_INTERNAL_GLPK=OFF"
+    "-DIGRAPH_USE_INTERNAL_GMP=OFF"
+    "-DIGRAPH_USE_INTERNAL_PLFIT=OFF"
+    "-DIGRAPH_GLPK_SUPPORT=ON"
+    "-DIGRAPH_GRAPHML_SUPPORT=ON"
+    "-DIGRAPH_OPENMP_SUPPORT=ON"
+    "-DIGRAPH_ENABLE_LTO=AUTO"
+    "-DIGRAPH_ENABLE_TLS=ON"
+    "-DBUILD_SHARED_LIBS=ON"
+  ];
+
+  doCheck = true;
+
+  postInstall = ''
+    mkdir -p "$out/share"
+    cp -r doc "$out/share"
+  '';
+
+  postFixup = ''
+    substituteInPlace $dev/lib/cmake/igraph/igraph-targets.cmake \
+      --replace-fail "_IMPORT_PREFIX \"$out\"" "_IMPORT_PREFIX \"$dev\""
+  ''
+  + lib.optionalString stdenv.hostPlatform.isDarwin ''
+    install_name_tool -change libblas.dylib ${blas}/lib/libblas.dylib $out/lib/libigraph.dylib
+  '';
+
+  meta = with lib; {
+    description = "C library for complex network analysis and graph theory";
+    homepage = "https://igraph.org/";
+    changelog = "https://github.com/igraph/igraph/blob/${finalAttrs.src.tag}/CHANGELOG.md";
+    license = licenses.gpl2Plus;
+    platforms = platforms.all;
+    inherit (hal-hardware-analyzer.meta) maintainers;
+  };
+})

pkgs/by-name/li/libleidenalg/package.nix

@@ -6,15 +6,15 @@
   igraph,
 }:
 
-stdenv.mkDerivation rec {
+stdenv.mkDerivation (finalAttrs: {
   pname = "libleidenalg";
-  version = "0.11.1";
+  version = "0.12.0";
 
   src = fetchFromGitHub {
     owner = "vtraag";
     repo = "libleidenalg";
-    tag = version;
-    hash = "sha256-hEES/OHvgN0yRDp5ZBZTCQfWr1j7s8NqE+Sp9WMHEEY=";
+    tag = finalAttrs.version;
+    hash = "sha256-ptfX31/1cUHLluc+Y+g28s4BEoGC0LqC9HH0cpkJRJQ=";
   };
 
   nativeBuildInputs = [
@@ -26,11 +26,11 @@ stdenv.mkDerivation rec {
   ];
 
   meta = {
-    changelog = "https://github.com/vtraag/libleidenalg/blob/${version}/CHANGELOG";
+    changelog = "https://github.com/vtraag/libleidenalg/blob/${finalAttrs.src.tag}/CHANGELOG";
     description = "C++ library of Leiden algorithm";
     homepage = "https://github.com/vtraag/libleidenalg";
     license = lib.licenses.gpl3Plus;
     maintainers = with lib.maintainers; [ dotlambda ];
     platforms = lib.platforms.all;
   };
-}
+})

pkgs/development/python-modules/igraph/default.nix

@@ -15,7 +15,7 @@
 
 buildPythonPackage rec {
   pname = "igraph";
-  version = "0.11.9";
+  version = "1.0.0";
 
   pyproject = true;
 
@@ -27,7 +27,7 @@ buildPythonPackage rec {
       # export-subst prevents reproducability
       rm $out/.git_archival.json
     '';
-    hash = "sha256-rmIICiIyEr5JCmkDAzcdisVaaKDraTQEquPHjK4d7oU=";
+    hash = "sha256-Y7ZQ1yNoD8A5b6c92OGz9Unietdg1uNt/Za6nxdCSP0=";
   };
 
   postPatch = ''

pkgs/development/python-modules/leidenalg/default.nix

@@ -6,26 +6,23 @@
   igraph,
   igraph-c,
   libleidenalg,
-  pythonOlder,
   setuptools-scm,
   unittestCheckHook,
 }:
 
 buildPythonPackage rec {
   pname = "leidenalg";
-  version = "0.10.2";
+  version = "0.11.0";
   pyproject = true;
 
-  disabled = pythonOlder "3.7";
-
   src = fetchFromGitHub {
     owner = "vtraag";
     repo = "leidenalg";
     tag = version;
-    hash = "sha256-oaTV+BIB/YQBWKrVXuiIEMH/1MxPxeHhjUzbmxt6hlw=";
+    hash = "sha256-u4xW1gsWDpbsFVLlOIiPZtpw9t4iFBC7fzwn04flev8=";
   };
 
-  nativeBuildInputs = [ setuptools-scm ];
+  build-system = [ setuptools-scm ];
 
   buildInputs = [
     igraph-c
@@ -34,18 +31,18 @@ buildPythonPackage rec {
 
   propagatedBuildInputs = [ igraph ];
 
-  checkInputs = [
+  nativeCheckInputs = [
     ddt
     unittestCheckHook
   ];
 
   pythonImportsCheck = [ "leidenalg" ];
 
-  meta = with lib; {
-    changelog = "https://github.com/vtraag/leidenalg/blob/${version}/CHANGELOG";
+  meta = {
+    changelog = "https://github.com/vtraag/leidenalg/blob/${src.tag}/CHANGELOG";
     description = "Implementation of the Leiden algorithm for various quality functions to be used with igraph in Python";
     homepage = "https://github.com/vtraag/leidenalg";
-    license = licenses.gpl3Only;
-    maintainers = with maintainers; [ jboy ];
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ jboy ];
   };
 }

pkgs/development/python-modules/textnets/default.nix

@@ -69,6 +69,11 @@ buildPythonPackage rec {
     pytestCheckHook
   ];
 
+  disabledTests = [
+    # https://github.com/jboynyc/textnets/issues/66
+    "test_textnet_save_and_load"
+  ];
+
   pythonImportsCheck = [ "textnets" ];
 
   # Enable the package to find the cythonized .so files during testing. See #255262